Operandos antes da frase WHEN

São interpretados de duas maneiras, dependendo de como são especificados:

• Individualmente, eles são chamados de assuntos de seleção.
• Coletivamente, eles são chamados de um conjunto de assuntos de seleção.

Operandos na frase WHEN

São interpretados de duas maneiras, dependendo de como são especificados:

• Individualmente, eles são chamados objetos de seleção
• Coletivamente, eles são chamados de um conjunto de objetos de seleção.

ALSO

Separa os assuntos de seleção em um conjunto de assuntos de seleção; separa os objetos de seleção em um conjunto de objetos de seleção.

THROUGH e THRU

São equivalentes.
Dois operandos conectados por uma frase THRU devem ser da mesma classe.
Os dois operandos assim conectados constituem um único objeto de seleção.

O número de objetos de seleção em cada conjunto de objetos de seleção deve ser igual ao número de assuntos de seleção.

Cada objeto de seleção dentro de um conjunto de objetos de seleção deve corresponder ao assunto de seleção com a mesma posição ordinal dentro do conjunto de assuntos de seleção, de acordo com as seguintes regras:

• Identificadores, literais ou expressões aritméticas que aparecem em um objeto de seleção devem ser operandos válidos para comparação com o operando correspondente no conjunto de assuntos de seleção.
  Para comparações envolvendo campos de data, consulte Comparação de campos de data.
• condition-1, condition-2 ou a palavra TRUE ou FALSE que aparece como um objeto de seleção deve corresponder a uma expressão condicional ou a palavra TRUE ou FALSE no conjunto de assuntos de seleção.
• A palavra QUALQUER pode corresponder a um assunto de seleção de qualquer tipo.

END-EVALUATE

Esse terminador de escopo explícito serve para delimitar o escopo da instrução EVALUATE.
END-EVALUATE permite que uma instrução EVALUATE condicional seja aninhada em outra instrução condicional.

Determinando valores

A execução da instrução EVALUATE opera como se cada sujeito de seleção e objeto de seleção tivesse sido avaliado e atribuído um valor numérico, alfanumérico, DBCS ou caractere nacional; um intervalo de valores numéricos, alfanuméricos, DBCS ou caracteres nacionais; ou um valor de verdade.
Esses valores são determinados da seguinte maneira:

• Qualquer assunto de seleção especificado pelo identifier-1 , identifier-2 , ... e qualquer objeto de seleção especificado pelo identifier-3 ou identifier-5 sem a frase NOT ou THRU recebem o valor e a classe do item de dados a que se referem.


• Qualquer assunto de seleção especificado por literal-1 , literal-2 , ... e qualquer objeto de seleção especificado por literal-3 ou literal-5 sem a frase NOT ou THRU recebem o valor e a classe do literal especificado.
  Se literal-3 ou literal-5 for a constante figurativa ZERO, QUOTE ou SPACE, a constante figurativa receberá a classe do assunto de seleção correspondente.


• Qualquer assunto de seleção no qual a expression-1, expression-2 , ... é especificada como expressão aritmética e qualquer objeto de seleção sem a frase NOT ou THRU na qual a arithmetic-expression-1 ou arithmetic-expression-3 é especificada atribuiu valores numéricos de acordo com as regras para avaliar uma expressão aritmética.
  (Consulte arithmetic_expressions - Expressões aritméticas.)
  
• Qualquer assunto de seleção no qual a expression-1, expression-2 , ... é especificada como expressão condicional e qualquer objeto de seleção no qual a condition-1 ou a condition-2 é especificada recebe um valor de verdade de acordo com as regras de avaliação expressões condicionais.


• Qualquer assunto de seleção ou qualquer objeto de seleção especificado pelas palavras TRUE ou FALSE recebe um valor de verdade.
  O valor de verdade "true" é atribuído aos itens especificados com a palavra TRUE, e o valor de verdade "false" é atribuído aos itens especificados com a palavra FALSE.


• Qualquer objeto de seleção especificado pela palavra ANY não é mais avaliado.


• Se a frase THRU for especificada para um objeto de seleção sem a frase NOT, o intervalo de valores incluirá todos os valores que, quando comparados ao assunto da seleção, são maiores ou iguais ao primeiro operando e menores ou iguais ao segundo operando, de acordo com para as regras de comparação.
  Se o primeiro operando for maior que o segundo, não haverá valores no intervalo.


• Se a frase NOT for especificada para um objeto de seleção, todos os valores atribuídos a esse item não serão iguais ao valor ou intervalo de valores que seriam atribuídos ao item se a frase NOT fosse omitida.

Comparando assuntos e objetos de seleção

A execução da instrução EVALUATE prossegue como se os valores atribuídos aos sujeitos e objetos de seleção fossem comparados para determinar se alguma frase WHEN satisfaz o conjunto de assuntos de seleção.
Essa comparação ocorre da seguinte maneira:

1. Cada objeto de seleção dentro do conjunto de objetos de seleção para a primeira frase WHEN é comparado ao assunto de seleção que possui a mesma posição ordinal no conjunto de assuntos de seleção.
   Uma das seguintes condições deve ser atendida para que a comparação seja atendida:
   1. Se os itens que estão sendo comparados tiverem valores numéricos, alfanuméricos, DBCS ou caracteres nacionais atribuídos, ou um intervalo de valores numéricos, alfanuméricos, DBCS ou caracteres nacionais, a comparação será satisfeita se o valor ou um valor no intervalo de valores, atribuído ao objeto de seleção é igual ao valor atribuído ao sujeito da seleção de acordo com as regras de comparação.
   2. Se os itens que estão sendo comparados tiverem valores de verdade designados, a comparação será satisfeita se os itens receberem valores de verdade idênticos.
   3. Se o objeto de seleção que está sendo comparado for especificado pela palavra ANY, a comparação será sempre satisfeita, independentemente do valor do assunto da seleção.
2. Se a comparação acima for atendida para cada objeto de seleção dentro do conjunto de objetos de seleção que está sendo comparado, a frase WHEN que contém esse conjunto de objetos de seleção é selecionada como aquela que satisfaz o conjunto de assuntos de seleção.
3. Se a comparação acima não for satisfeita para todos os objetos de seleção dentro do conjunto de objetos de seleção que estão sendo comparados, esse conjunto de objetos de seleção não satisfaz o conjunto de assuntos de seleção.
4. Este procedimento é repetido para conjuntos subsequentes de objetos de seleção na ordem em que aparecem no texto de origem, até que uma frase WHEN que satisfaça o conjunto de assuntos de seleção seja selecionada ou até que todos os conjuntos de objetos de seleção estejam esgotados.

Executando a instrução EVALUATE

Após a conclusão da operação de comparação, a execução da instrução EVALUATE continua da seguinte maneira:

• Se uma frase WHEN for selecionada, a execução continuará com a primeira declaração imperative-statement-1 após a frase WHEN selecionada.
  Observe que várias instruções WHEN são permitidas para uma única imperative-statement-1.
• Se nenhuma frase WHEN for selecionada e uma frase WHEN OTHER for especificada, a execução continuará com a imperative-statement-2.
• Se nenhuma frase WHEN for selecionada e nenhuma frase WHEN OTHER for especificada, a execução continuará com a próxima instrução executável após o delimitador de escopo.
• O escopo de execução da instrução EVALUATE é finalizado quando a execução atinge o final do escopo da frase WHEN ou WHEN OTHER selecionada, ou quando nenhuma frase WHEN é selecionada e nenhuma frase WHEN OTHER é especificada.

• Se a variável de nome ACONTA for 0 (zero), o fluxo avaliará a variável de nome BCONTA.
• Para cada valor possível especificado neste fluxo para essa variável, o programa efetuará uma ação diferente.
• Não se importe com as declarações IF e END-IF dentro das condições.

           EVALUATE IDADE                         
               WHEN  0 THRU 19                    
                    PERFORM R100-ROTINA-MENOR     
               WHEN 20 THRU 99                    
                    PERFORM R200-ROTINA-ADULTO    
               WHEN OTHER                         
                    PERFORM R900-ROTINA-VER-IDADE 
           END-EVALUATE.

           EVALUATE TRUE                         
               WHEN IDADE >=  0 AND <= 19        
                    PERFORM R100-ROTINA-MENOR    
               WHEN IDADE >= 20 AND <= 99        
                    PERFORM R200-ROTINA-ADULTO   
               WHEN OTHER                        
                    PERFORM R900-ROTINA-VER-IDADE
           END-EVALUATE.

           EVALUATE IDADE <= 19               
               WHEN TRUE                      
                    PERFORM R100-ROTINA-MENOR 
               WHEN FALSE                     
                    PERFORM R200-ROTINA-ADULTO
           END-EVALUATE.

           EVALUATE TRUE                      
               WHEN IDADE <= 19               
                    PERFORM R100-ROTINA-MENOR 
               WHEN OTHER                     
                    PERFORM R200-ROTINA-ADULTO
           END-EVALUATE.

      *    As variáveis WSS-CONTA-01 e WSS-CONTA-02 podem conter os valores 10, 20 ou 30 
      *    e todas as combinações possiveis entre eles   

           WSS-CONTA-01 = 10 E WSS-CONTA-02 = 10
           WSS-CONTA-01 = 10 E WSS-CONTA-02 = 20
           WSS-CONTA-01 = 10 E WSS-CONTA-02 = 30

           WSS-CONTA-01 = 20 E WSS-CONTA-02 = 10
           WSS-CONTA-01 = 20 E WSS-CONTA-02 = 20
           WSS-CONTA-01 = 20 E WSS-CONTA-02 = 30

           WSS-CONTA-01 = 30 E WSS-CONTA-02 = 10
           WSS-CONTA-01 = 30 E WSS-CONTA-02 = 20
           WSS-CONTA-01 = 30 E WSS-CONTA-02 = 30
      

      *    Por favor esqueçam essa codificação
         
           IF WSS-CONTA-01 EQUAL 10 AND 
              WSS-CONTA-02 EQUAL 10
              PERFORM P1010-PROCESSA THRU P1010-FIM
           ELSE
              IF WSS-CONTA-01 EQUAL 10 AND 
                 WSS-CONTA-02 EQUAL 20
                 PERFORM P1020-PROCESSA THRU P1020-FIM
              ELSE
                 IF WSS-CONTA-01 EQUAL 10 AND 
                    WSS-CONTA-02 EQUAL 30
                    PERFORM P1030-PROCESSA THRU P1030-FIM
                 ELSE
                    IF WSS-CONTA-01 EQUAL 20 AND 
                       WSS-CONTA-02 EQUAL 10
                       PERFORM P2010-PROCESSA THRU P2010-FIM
                    ELSE
                       IF WSS-CONTA-01 EQUAL 20 AND
                          WSS-CONTA-02 EQUAL 20
                          PERFORM P2020-PROCESSA THRU P2020-FIM
                       ELSE
                          IF WSS-CONTA-01 EQUAL 20 AND 
                             WSS-CONTA-02 EQUAL 30
                             PERFORM P2030-PROCESSA THRU P2030-FIM
                          ELSE 
                             IF WSS-CONTA-01 EQUAL 30 AND
                                WSS-CONTA-02 EQUAL 10
                                PERFORM P3010-PROCESSA THRU P3010-FIM
                             ELSE 
                                IF WSS-CONTA-01 EQUAL 30 AND 
                                   WSS-CONTA-02 EQUAL 20
                                   PERFORM P3020-PROCESSA THRU P3020-FIM
                                ELSE
                                   PERFORM P3030-PROCESSA THRU P3030-FIM
                                END-IF
                             END-IF
                          END-IF
                       END-IF
                    END-IF
                 END-IF
              END-IF
           END-IF

      *    Por favor esqueçam essa codificação, tambem
 
           IF WSS-CONTA-01 EQUAL 10
              IF WSS-CONTA-02 EQUAL 10
                 PERFORM P1010-PROCESSA THRU P1010-FIM
              ELSE
                 IF WSS-CONTA-02 EQUAL 20
                    PERFORM P1020-PROCESSA THRU P1020-FIM
                 ELSE
                    PERFORM P1030-PROCESSA THRU P1030-FIM
                 END-IF
              END-IF
           ELSE 
              IF WSS-CONTA-01 EQUAL 20
                 IF WSS-CONTA-02 EQUAL 10
                    PERFORM P2010-PROCESSA THRU P2010-FIM
                 ELSE
                    IF WSS-CONTA-02 EQUAL 20
                       PERFORM P2020-PROCESSA THRU P2020-FIM
                    ELSE
                       PERFORM P2030-PROCESSA THRU P2030-FIM
                    END-IF
                 END-IF
              ELSE 
                 IF WSS-CONTA-02 EQUAL 10
                    PERFORM P3010-PROCESSA THRU P3010-FIM
                 ELSE
                    IF WSS-CONTA-02 EQUAL 20
                       PERFORM P3020-PROCESSA THRU P3020-FIM
                    ELSE
                       PERFORM P3030-PROCESSA THRU P3030-FIM
                    END-IF
                 END-IF
              END-IF
           END-IF

      *    Codificação recomendável
 
           EVALUATE TRUE
              WHEN WSS-CONTA-01 EQUAL 10 
                   EVALUATE WSS-CONTA-02 
                      WHEN 10    PERFORM P1010-PROCESSA THRU P1010-FIM
                      WHEN 20    PERFORM P1020-PROCESSA THRU P1020-FIM
                      WHEN OTHER PERFORM P1030-PROCESSA THRU P1030-FIM
                   END-EVALUATE 
              WHEN WSS-CONTA-01 EQUAL 20 
                   EVALUATE WSS-CONTA-02 
                      WHEN 10    PERFORM P2010-PROCESSA THRU P2010-FIM
                      WHEN 20    PERFORM P2020-PROCESSA THRU P2020-FIM
                      WHEN OTHER PERFORM P2030-PROCESSA THRU P2030-FIM
                   END-EVALUATE 
              WHEN OTHER 
                   EVALUATE WSS-CONTA-02 
                      WHEN 10    PERFORM P3010-PROCESSA THRU P3010-FIM
                      WHEN 20    PERFORM P3020-PROCESSA THRU P3020-FIM
                      WHEN OTHER PERFORM P3030-PROCESSA THRU P3030-FIM
                   END-EVALUATE 
           END-EVALUATE
      

      *    Se fizeres essa combinação melhor ainda
      *    crie tres variáveis 

      *-----------------------------------------------------------------
       WORKING-STORAGE SECTION
      *-----------------------------------------------------------------

       01  WSS-AUXILIARES.
           05  WSS-CONTA               PIC 9(004)      VALUE ZEROES. 
           05  WSS-CONTA-R             REDEFINES WSS-CONTA.
               10  WS-CONTA-01-N       PIC 9(002).                        
               10  WS-CONTA-02-N       PIC 9(002).                        

      *-----------------------------------------------------------------
       PROCEDURE DIVISION.
      *-----------------------------------------------------------------

           MOVE WSS-CONTA-01 TO WSS-CONTA-01-N
           MOVE WSS-CONTA-02 TO WSS-CONTA-02-N

           EVALUATE WSS-CONTA
                    WHEN 1010  PERFORM P1010-PROCESSA THRU P1010-FIM
                    WHEN 1020  PERFORM P1020-PROCESSA THRU P1020-FIM
                    WHEN 1030  PERFORM P1030-PROCESSA THRU P1030-FIM
                    WHEN 2010  PERFORM P2010-PROCESSA THRU P2010-FIM
                    WHEN 2020  PERFORM P2020-PROCESSA THRU P2020-FIM
                    WHEN 2030  PERFORM P2030-PROCESSA THRU P2030-FIM
                    WHEN 3010  PERFORM P3010-PROCESSA THRU P3010-FIM
                    WHEN 3020  PERFORM P3020-PROCESSA THRU P3020-FIM
                    WHEN OTHER PERFORM P3030-PROCESSA THRU P3030-FIM
           END-EVALUATE
      

 
 Este exemplo do comando EVALUATE é um pouco mais complexo e tem abaixo do mesmo o 
 equivalente ao comando IF.

 Exemplo mais complexo do comando EVALUATE:

           EVALUATE A = B ALSO C > D ALSO TRUE
                    WHEN TRUE  ALSO TRUE  ALSO E = F + 15
                         PERFORM ROTINA-1
                    WHEN TRUE  ALSO TRUE  ALSO E > 12
                         PERFORM ROTINA-2
                    WHEN TRUE  ALSO FALSE ALSO ANY
                         PERFORM ROTINA-3
                    WHEN FALSE ALSO TRUE  ALSO ANY
                         PERFORM ROTINA-4
                    WHEN FALSE ALSO FALSE ALSO ANY
                         PERFORM ROTINA-5
           END-EVALUATE.

 O comando IF equivalente ao EVALUATE acima: 


           IF A EQUAL B 
              IF C GREATER THAN D 
                 IF E EQUAL F + 15 
                    PERFORM ROTINA-1
                 ELSE
                    IF E GREATER THAN 12 
                       PERFORM ROTINA-2
                    END-IF
                 END-IF
              ELSE
                 PERFORM ROTINA-3
              END-IF
           ELSE
              IF C GREATER THAN D 
                 PERFORM ROTINA-4
              ELSE
                 PERFORM ROTINA-5
              END-IF
           END-IF
      

 
 Outro exemplo mais complexo do comando EVALUATE:

      *-----------------------------------------------------------------
       WORKING-STORAGE SECTION. 
      *-----------------------------------------------------------------

       01  WS-AUXILIARES. 
           05 WS-IDADE             PIC 9(003). 
           05 WS-SEXO              PIC X(001). 
           05 WS-DESCRICAO         PIC X(020). 
           05 A                    PIC 9(003). 
           05 B                    PIC 9(004). 
           05 C                    PIC 9(004). 
           05 D                    PIC 9(004). 
           05 E                    PIC 9(005). 
           05 F                    PIC 9(006). 

      *-----------------------------------------------------------------
       PROCEDURE DIVISION. 
      *-----------------------------------------------------------------

           EVALUATE TRUE ALSO TRUE                                     
               WHEN WS-IDADE < 13 ALSO WS-SEXO = 'M'                  
                    MOVE 'MENINO JOVEM'       TO WS-DESCRICAO          
               WHEN WS-IDADE < 13 ALSO WS-SEXO = 'F'                   
                    MOVE 'MENINA JOVEM'       TO WS-DESCRICAO          
               WHEN WS-IDADE > 12 AND WS-IDADE < 20 ALSO WS-SEXO = 'M' 
                    MOVE 'MENINO ADOLESCENTE' TO WS-DESCRICAO          
               WHEN WS-IDADE > 12 AND WS-IDADE < 20 ALSO WS-SEXO = 'F' 
                    MOVE 'MENINA ADOLESCENTE' TO WS-DESCRICAO          
               WHEN WS-IDADE > 19 ALSO WS-SEXO = 'M'          
                    MOVE 'HOMEM ADULTO'       TO WS-DESCRICAO          
               WHEN WS-IDADE > 19 ALSO WS-SEXO = 'F'          
                    MOVE 'MULHER ADULTA'      TO WS-DESCRICAO          
               WHEN OTHER         
                    MOVE 'DADOS INVALIDOS'    TO WS-DESCRICAO          
           END-EVALUATE 

           EVALUATE TRUE ALSO TRUE
               WHEN A + B < 10 ALSO C = 10
                    MOVE 'CASO 1'             TO WS-DESCRICAO
               WHEN A + B > 50 ALSO C = ( D + E ) / F
                    MOVE 'CASO 2'             TO WS-DESCRICAO
               WHEN OTHER
                    MOVE 'OUTROS CASOS'       TO WS-DESCRICAO
           END-EVALUATE.