COBOL - SEARCH e SEARCH ALL: Pesquisando em tabelas internas



Desenvolvido por DORNELLES Carlos Alberto - Analista de Sistemas - Brasília DF. - cad_cobol@hotmail.com

COBOL - SEARCH e SEARCH ALL: Pesquisando em tabelas internas

Como comentei em outro artigo que publiquei por aqui, tabela interna é o nome dado pelo COBOL a um conjunto homogêneo de dados que se repetem.
São semelhantes aos arrays que existem em outras linguagens, podem ser criadas com tamanhos variáveis, mas não podem ser expandidas dinamicamente em tempo de execução.

Neste artigo aqui vamos mostrar os comandos disponíveis no COBOL para localizar ocorrências dentro de uma tabela interna e fazer algumas considerações sobre performance.

Para isso, vamos trabalhar com uma tabela composta por código da unidade da federação e nome do Estado:

01  CONTEUDO. 
    03  FILLER      PIC X(22) VALUE "ACACRE                ".
    03  FILLER      PIC X(22) VALUE "ALALAGOAS             ".
    03  FILLER      PIC X(22) VALUE "AMAMAZONAS            ".
    03  FILLER      PIC X(22) VALUE "APAMAPA               ".
    03  FILLER      PIC X(22) VALUE "BABAHIA               ".
    03  FILLER      PIC X(22) VALUE "CECEARA               ".
    03  FILLER      PIC X(22) VALUE "DFDISTRITO FEDERAL    ".
    03  FILLER      PIC X(22) VALUE "ESESPIRITO SANTO      ".
    03  FILLER      PIC X(22) VALUE "FNFERNANDO DE NORONHA ".
    03  FILLER      PIC X(22) VALUE "GOGOIAS               ".
    03  FILLER      PIC X(22) VALUE "MAMARANHAO            ".
    03  FILLER      PIC X(22) VALUE "MGMINAS GERAIS        ".
    03  FILLER      PIC X(22) VALUE "MSMATO GROSSO DO SUL  ".
    03  FILLER      PIC X(22) VALUE "MTMATO GROSSO         ".
    03  FILLER      PIC X(22) VALUE "PAPARA                ".
    03  FILLER      PIC X(22) VALUE "PBPARAIBA             ".
    03  FILLER      PIC X(22) VALUE "PEPERNAMBUCO          ".
    03  FILLER      PIC X(22) VALUE "PIPIAUI               ".
    03  FILLER      PIC X(22) VALUE "PRPARANA              ".
    03  FILLER      PIC X(22) VALUE "RJRIO DE JANEIRO      ".
    03  FILLER      PIC X(22) VALUE "RNRIO GRANDE DO NORTE ".
    03  FILLER      PIC X(22) VALUE "RORONDONIA            ".
    03  FILLER      PIC X(22) VALUE "RRRORAIMA             ".
    03  FILLER      PIC X(22) VALUE "RSRIO GRANDE DO SUL   ".
    03  FILLER      PIC X(22) VALUE "SCSANTA CATARINA      ".
    03  FILLER      PIC X(22) VALUE "SESERGIPE             ".
    03  FILLER      PIC X(22) VALUE "SPSAO PAULO           ".
    03  FILLER      PIC X(22) VALUE "TOTOCANTINS           ".
01  FILLER REDEFINES CONTEUDO.    
    03  TABELA      OCCURS 28 INDEXED BY INDICE.
        05  CD-UF   PIC X(02).
        05  NM-UF   PIC X(20).

Nos exemplos a seguir vamos procurar o nome do Estado associado a um determinado código de unidade federativa.

Se não houvesse o comando SEARCH

A pesquisa em tabelas internas pode ser realizada com comandos básicos do COBOL.
Um PERFORM para o loop e um IF para localizar o dado que se procura são suficientes.

O exemplo abaixo mostra esse tipo de abordagem:

IDENTIFICATION DIVISION.
PROGRAM-ID. GTC011.

DATA DIVISION.
WORKING-STORAGE SECTION.
*> VARIAVEIS DE TRABALHO
77 CD-UF-A-PROCURAR PIC X(02) VALUE SPACES.
77 NM-UF-ENCONTRADO PIC X(20) VALUE SPACES.
77 SUBSCRITO        PIC 9(02) VALUE ZEROS.

*> Tabela interna
01  CONTEUDO. 
    03  FILLER      PIC X(22) VALUE "ACACRE                ".
    03  FILLER      PIC X(22) VALUE "ALALAGOAS             ".
    03  FILLER      PIC X(22) VALUE "AMAMAZONAS            ".
    03  FILLER      PIC X(22) VALUE "APAMAPA               ".
    03  FILLER      PIC X(22) VALUE "BABAHIA               ".
    03  FILLER      PIC X(22) VALUE "CECEARA               ".
    03  FILLER      PIC X(22) VALUE "DFDISTRITO FEDERAL    ".
    03  FILLER      PIC X(22) VALUE "ESESPIRITO SANTO      ".
    03  FILLER      PIC X(22) VALUE "FNFERNANDO DE NORONHA ".
    03  FILLER      PIC X(22) VALUE "GOGOIAS               ".
    03  FILLER      PIC X(22) VALUE "MAMARANHAO            ".
    03  FILLER      PIC X(22) VALUE "MGMINAS GERAIS        ".
    03  FILLER      PIC X(22) VALUE "MSMATO GROSSO DO SUL  ".
    03  FILLER      PIC X(22) VALUE "MTMATO GROSSO         ".
    03  FILLER      PIC X(22) VALUE "PAPARA                ".
    03  FILLER      PIC X(22) VALUE "PBPARAIBA             ".
    03  FILLER      PIC X(22) VALUE "PEPERNAMBUCO          ".
    03  FILLER      PIC X(22) VALUE "PIPIAUI               ".
    03  FILLER      PIC X(22) VALUE "PRPARANA              ".
    03  FILLER      PIC X(22) VALUE "RJRIO DE JANEIRO      ".
    03  FILLER      PIC X(22) VALUE "RNRIO GRANDE DO NORTE ".
    03  FILLER      PIC X(22) VALUE "RORONDONIA            ".
    03  FILLER      PIC X(22) VALUE "RRRORAIMA             ".
    03  FILLER      PIC X(22) VALUE "RSRIO GRANDE DO SUL   ".
    03  FILLER      PIC X(22) VALUE "SCSANTA CATARINA      ".
    03  FILLER      PIC X(22) VALUE "SESERGIPE             ".
    03  FILLER      PIC X(22) VALUE "SPSAO PAULO           ".
    03  FILLER      PIC X(22) VALUE "TOTOCANTINS           ".
01  FILLER REDEFINES CONTEUDO.    
    03  TABELA      OCCURS 28.
        05  CD-UF   PIC X(02).
        05  NM-UF   PIC X(20).

PROCEDURE DIVISION.
INICIO.

    DISPLAY "Informe um código da federacao: "
    ACCEPT CD-UF-A-PROCURAR FROM CONSOLE

    PERFORM VARYING SUBSCRITO FROM 1 BY 1 UNTIL SUBSCRITO > 28
        IF CD-UF(SUBSCRITO) = CD-UF-A-PROCURAR
            MOVE NM-UF(SUBSCRITO) TO NM-UF-ENCONTRADO
            EXIT PERFORM
        END-IF
    END-PERFORM
    
    IF NM-UF-ENCONTRADO = SPACES
        DISPLAY "UF nao encontrada"
    ELSE
        DISPLAY CD-UF-A-PROCURAR "=" NM-UF-ENCONTRADO
    END-IF

    STOP RUN.

Este programa permite que o usuário digite um código de unidade federativa, busca esse código na tabela interna e exibe o nome do Estado correspondente.
Se o código não for encontrado, exibe a mensagem "UF não encontrada".

As variáveis de trabalho definidas no programa servem para armazenar o código da UF que o usuário deseja procurar (cd-uf-a-procurar), o nome do Estado encontrado (nm-uf-encontrado) e um subscrito que será usado para varrer todas as ocorrências da tabela.

As linhas abaixo mostram o programa em execução:

[aeisxpad ~/cbl]$ gtc011
Informe um código da federacao:
RJ
RJ=RIO DE JANEIRO
[aeisxpad ~/cbl]$ gtc011
Informe um código da federacao:
xx
UF nao encontrada

Search sequencial

O comando SEARCH faz basicamente o que o PERFORM VARYING e o IF fizeram no programa anterior.
A única diferença é que um índice precisa ser criado na tabela interna, e esse índice precisa ser inicializado antes da execução do SEARCH.

A tabela ficaria assim:

01  FILLER REDEFINES CONTEUDO.
    03 TABELA OCCURS 28 INDEXED BY INDICE.
       05 CD-UF   PIC X(02).
       05 NM-UF   PIC X(20).

E na PROCEDURE DIVISION poderíamos eliminar o PERFORM e substituir pelo SEARCH:

PROCEDURE DIVISION.
INICIO.

    DISPLAY "Informe um código da federacao: "
    accept cd-uf-a-procurar from console

    SET INDICE TO 1
    SEARCH TABELA VARYING INDICE
        AT END
            DISPLAY "UF nao encontrada"
        WHEN CD-UF(INDICE) = CD-UF-A-PROCURAR
            DISPLAY CD-UF-A-PROCURAR "=" NM-UF(INDICE)
    END-SEARCH

    STOP RUN.

Alguns comentários sobre o comando SEARCH:

  • A pesquisa começa na ocorrência que corresponde ao valor que está no índice.
    Por isso temos que inicializá-lo com 1.
  • O único comando que se pode usar para atribuição de valor a índices é SET.
    Por isso escrevemos SET 1 TO INDICE, e não MOVE 1 TO INDICE.
  • O objeto do comando deve ser aquele que foi declarado com a cláusula OCCURS.
    No exemplo acima não seria possível, por exemplo, fazer um SEARCH em "CD-UF", porque esse item elementar não possui a cláusula OCCURS.
  • A frase WHEN estabelece a condição para a que pesquisa seja considerada bem sucedida.
    Nesse exemplo, ela será bem sucedida quando um determinado código de UF da tabela for igual ao código informado pelo usuário.
    Por isso, WHEN CD-UF(INDICE) = CD-UF-A-PROCURAR.
  • O comando termina quando a condição do WHEN é considerada verdadeira.
  • É possível definir mais de uma cláusula WHEN, com diferentes condições.
    O SEARCH irá parar quando qualquer uma das condições for considerada verdadeira.
  • A frase AT END só é executada se a pesquisa chegar ao fim da tabela e nenhuma condição WHEN foi considerada verdadeira.

Search binário

O search binário produz uma pesquisa mais rápida do que o search sequencial.
Sintaticamente a mudança é pequena: inserir a palavra ALL após o comando e remover a cláusula VARYING, como no exemplo abaixo:

SEARCH ALL TABELA
    AT END
        DISPLAY "UF nao encontrada"
    WHEN CD-UF(INDICE) = CD-UF-A-PROCURAR
        DISPLAY CD-UF-A-PROCURAR "=" NM-UF(INDICE)
END-SEARCH 

Apesar dessa pequena diferença, o algoritmo implementado pelo compilador é muito mais eficiente.
O fluxo abaixo mostra como esse processo funciona na tabela que estamos usando em nossos exemplos:

Figura 1. Fluxo do algoritmo do SEARCH ALL.

Repare que no SEARCH ALL nem todas as ocorrências da tabela serão percorridas.
O algoritmo avalia se, na posição corrente do índice, o valor da chave é igual, maior ou menor do que o valor procurado.
E vai ajustando os valores dos ponteiros em função do resultado dessas comparações.
Os ponteiros são internos e não precisam ser declarados pelo programa.

O efeito disso é que, enquanto no pior cenário do search sequencial toda a tabela é percorrida, no search binário apenas uma fração das ocorrências da tabela precisa ser testada.

Mas para que o SEARCH ALL funcione existem duas condições.

  1. É preciso declarar uma chave para a tabela através das opções ASCENDING ou DESCENDING da cláusula OCCURS.
    A tabela do nosso exemplo ficaria assim:
*> Tabela interna
01  CONTEUDO.
    03 FILLER PIC X(22) VALUE "ACACRE ".
    03 FILLER PIC X(22) VALUE "ALALAGOAS ".
    03 FILLER PIC X(22) VALUE "AMAMAZONAS ".
    03 FILLER PIC X(22) VALUE "APAMAPA ".   
    03 FILLER PIC X(22) VALUE "BABAHIA ".
    03 FILLER PIC X(22) VALUE "CECEARA ".
    03 FILLER PIC X(22) VALUE "DFDISTRITO FEDERAL ".
    03 FILLER PIC X(22) VALUE "ESESPIRITO SANTO ".
    03 FILLER PIC X(22) VALUE "FNFERNANDO DE NORONHA ".
    03 FILLER PIC X(22) VALUE "GOGOIAS ".
    03 FILLER PIC X(22) VALUE "MAMARANHAO ".
    03 FILLER PIC X(22) VALUE "MGMINAS GERAIS ".
    03 FILLER PIC X(22) VALUE "MSMATO GROSSO DO SUL ".
    03 FILLER PIC X(22) VALUE "MTMATO GROSSO ".
    03 FILLER PIC X(22) VALUE "PAPARA ".
    03 FILLER PIC X(22) VALUE "PBPARAIBA ".
    03 FILLER PIC X(22) VALUE "PEPERNAMBUCO ".
    03 FILLER PIC X(22) VALUE "PIPIAUI ".
    03 FILLER PIC X(22) VALUE "PRPARANA ".
    03 FILLER PIC X(22) VALUE "RJRIO DE JANEIRO ".
    03 FILLER PIC X(22) VALUE "RNRIO GRANDE DO NORTE ".
    03 FILLER PIC X(22) VALUE "RORONDONIA ".
    03 FILLER PIC X(22) VALUE "RRRORAIMA ".
    03 FILLER PIC X(22) VALUE "RSRIO GRANDE DO SUL ".
    03 FILLER PIC X(22) VALUE "SCSANTA CATARINA ".
    03 FILLER PIC X(22) VALUE "SESERGIPE ".
    03 FILLER PIC X(22) VALUE "SPSAO PAULO ".
    03 FILLER PIC X(22) VALUE "TOTOCANTINS ".
01 FILLER REDEFINES CONTEUDO.
    03 TABELA OCCURS 28 ASCENDING KEY CD-UF INDEXED BY INDICE.
        05 CD-UF PIC X(02).
        05 NM-UF PIC X(20).

2. O conteúdo da tabela precisa estar ordenado de acordo com o que foi informado.
Nesse exemplo, o conteúdo precisa estar classificado em ordem ascendente pelo campo cd-uf.

Duas situações podem acontecer se uma das duas regras acima não forem respeitadas:
(1) Se não houver opção ASCENDING/DESCENDING na cláusula OCCURS e o programa tentar executar um SEARCH ALL, o compilador exibirá uma mensagem de erro durante a compilação;
(2) Se houver opção ASCENDING/DESCENDING, mas o conteúdo não estiver ordenado de acordo com a opção, o programa vai compilar mas os resultados da pesquisa provavelmente serão incorretos.

Comparações de performance

Para mostrar a diferença de performance das três abordagens eu compilei o programa abaixo no GnuCOBOL e o executei no Linux.
Ele é apenas uma versão adaptada dos três exemplos que vimos antes.

IDENTIFICATION DIVISION.
PROGRAM-ID. GTC014.

DATA DIVISION.
WORKING-STORAGE SECTION.
*> Variaveis de trabalho
77  CD-UF-A-PROCURAR PIC X(02) VALUE SPACES.
77  NM-UF-ENCONTRADO PIC X(20) VALUE SPACES.
77  HORA-INICIO      PIC 9(08) VALUE ZEROS.
77  HORA-TERMINO     PIC 9(08) VALUE ZEROS.
77  SUBSCRITO        PIC 9(02) VALUE ZEROS.
*> Constantes             
77 LOOP              PIC 9(07) VALUE 1000000.

*> Tabela interna
01  CONTEUDO. 
    03  FILLER      PIC X(22) VALUE "ACACRE                ".
    03  FILLER      PIC X(22) VALUE "ALALAGOAS             ".
    03  FILLER      PIC X(22) VALUE "AMAMAZONAS            ".
    03  FILLER      PIC X(22) VALUE "APAMAPA               ".
    03  FILLER      PIC X(22) VALUE "BABAHIA               ".
    03  FILLER      PIC X(22) VALUE "CECEARA               ".
    03  FILLER      PIC X(22) VALUE "DFDISTRITO FEDERAL    ".
    03  FILLER      PIC X(22) VALUE "ESESPIRITO SANTO      ".
    03  FILLER      PIC X(22) VALUE "FNFERNANDO DE NORONHA ".
    03  FILLER      PIC X(22) VALUE "GOGOIAS               ".
    03  FILLER      PIC X(22) VALUE "MAMARANHAO            ".
    03  FILLER      PIC X(22) VALUE "MGMINAS GERAIS        ".
    03  FILLER      PIC X(22) VALUE "MSMATO GROSSO DO SUL  ".
    03  FILLER      PIC X(22) VALUE "MTMATO GROSSO         ".
    03  FILLER      PIC X(22) VALUE "PAPARA                ".
    03  FILLER      PIC X(22) VALUE "PBPARAIBA             ".
    03  FILLER      PIC X(22) VALUE "PEPERNAMBUCO          ".
    03  FILLER      PIC X(22) VALUE "PIPIAUI               ".
    03  FILLER      PIC X(22) VALUE "PRPARANA              ".
    03  FILLER      PIC X(22) VALUE "RJRIO DE JANEIRO      ".
    03  FILLER      PIC X(22) VALUE "RNRIO GRANDE DO NORTE ".
    03  FILLER      PIC X(22) VALUE "RORONDONIA            ".
    03  FILLER      PIC X(22) VALUE "RRRORAIMA             ".
    03  FILLER      PIC X(22) VALUE "RSRIO GRANDE DO SUL   ".
    03  FILLER      PIC X(22) VALUE "SCSANTA CATARINA      ".
    03  FILLER      PIC X(22) VALUE "SESERGIPE             ".
    03  FILLER      PIC X(22) VALUE "SPSAO PAULO           ".
    03  FILLER      PIC X(22) VALUE "TOTOCANTINS           ".
01  FILLER REDEFINES CONTEUDO.    
    03  TABELA      OCCURS 28 ASCENDING KEY CD-UF INDEXED BY INDICE.
        05  CD-UF   PIC X(02).
        05  NM-UF   PIC X(20).

PROCEDURE DIVISION.

000-INICIO.

    ACCEPT HORA-INICIO FROM TIME
    PERFORM LOOP TIMES
        MOVE "FN" TO CD-UF-A-PROCURAR
        PERFORM 100-PESQUISA-COM-PERFORM VARYING SUBSCRITO FROM 1 BY 1 UNTIL SUBSCRITO > 28
        MOVE "RJ" TO CD-UF-A-PROCURAR
        PERFORM 100-PESQUISA-COM-PERFORM VARYING SUBSCRITO FROM 1 BY 1 UNTIL SUBSCRITO > 28
    END-PERFORM
    ACCEPT HORA-TERMINO FROM TIME
    DISPLAY "Pesquisa com PERFORM VARYING..: de " HORA-INICIO " a " HORA-TERMINO

    ACCEPT HORA-INICIO FROM TIME
    PERFORM LOOP TIMES
        MOVE "FN" TO CD-UF-A-PROCURAR
        PERFORM 200-PESQUISA-SEARCH-SEQUENCIAL
        MOVE "RJ" TO CD-UF-A-PROCURAR
        PERFORM 200-PESQUISA-SEARCH-SEQUENCIAL
    END-PERFORM
    ACCEPT HORA-TERMINO FROM TIME
    DISPLAY "Pesquisa com SEARCH SEQUENCIAL: de " HORA-INICIO " a " HORA-TERMINO

    ACCEPT HORA-INICIO FROM TIME
    PERFORM LOOP TIMES
        MOVE "FN" TO CD-UF-A-PROCURAR
        PERFORM 300-PESQUISA-SEARCH-BINARIO
        MOVE "RJ" TO CD-UF-A-PROCURAR   
        PERFORM 300-PESQUISA-SEARCH-BINARIO
    END-PERFORM
    ACCEPT HORA-TERMINO FROM TIME
    DISPLAY "Pesquisa com SEARCH BINARIO...: de " HORA-INICIO " a " HORA-TERMINO

    STOP RUN.
    
100-PESQUISA-COM-PERFORM.

    IF CD-UF(SUBSCRITO) = CD-UF-A-PROCURAR
        EXIT PARAGRAPH
    END-IF.

200-PESQUISA-SEARCH-SEQUENCIAL.

    SET INDICE TO 1
    SEARCH TABELA VARYING INDICE
        AT END
            DISPLAY "UF nao encontrada"
        WHEN CD-UF(INDICE) = CD-UF-A-PROCURAR
            EXIT PARAGRAPH
    END-SEARCH.

300-PESQUISA-SEARCH-BINARIO.

    SET INDICE TO 1
    SEARCH ALL TABELA 
        AT END
            DISPLAY "UF nao encontrada"
        WHEN CD-UF(INDICE) = CD-UF-A-PROCURAR
            EXIT PARAGRAPH
    END-SEARCH.

Ele é dividido em três blocos.

Cada bloco executa uma das abordagens ou soluções que vimos até aqui: pesquisa com PERFORM VARYING, pesquisa com SEARCH SEQUENCIAL e pesquisa com SEARCH BINARIO.

Todos os blocos procuram duas unidades da federação fixas: FN (Fernando de Noronha) e RJ (Rio de Janeiro), que dividem a tabela mais ou menos em três partes iguais.

Cada bloco é executado 1.000.000 de vezes. A quantidade de iterações é definida por uma constante chamada LOOP que foi definida na WORKING-STORAGE.

Guardamos a hora do sistema, com centésimos de segundo, antes e depois da execução de cada bloco.
As horas de início e término são exibidas ao final do bloco.

O resultado foi o seguinte:

Pesquisa com PERFORM VARYING..: de 09225618 a 09230497
Pesquisa com SEARCH SEQUENCIAL: de 09230497 a 09230518
Pesquisa com SEARCH BINARIO...: de 09230518 a 09230525

E os tempos obtidos foram:

  • PERFORM VARYING : 8 segundos e 79 centésimos
  • SEARCH SEQUENCIAL: 21 centésimos
  • SEARCH BINARIO : 7 centésimos